Robot Framework

pip install tracera-robot

Python ≥ 3.11 और Robot Framework ≥ 7 आवश्यक (देखें ऑटोटेस्ट एडेप्टर)। tracera-robot PyPI पर।

listener रजिस्टर करें:

robot --listener tracera_robot.listener.TraceraListener suite.robot

comment, error, attachment, Tracera Step और Tracera Test Case के लिए वैकल्पिक साथी लाइब्रेरी:

*** Settings ***
Library    tracera_robot.keywords.TraceraKeywords

एनवायरनमेंट वेरिएबल और रन मोड: ऑटोटेस्ट एडेप्टर।

`testCaseId` और `autotestName` बाँधना

टेस्ट पर टैग पसंद करें।

*** Test Cases ***
Login
    [Tags]    tracera.id:42    tracera.name:e2e/login
    Log    hello

ज़रूरत हो तो tracera.name में स्पेस और विशेष वर्ण एन्कोड करें (e2e%2Flogin)। यदि tracera.name न लिखा हो, तो autotestName Robot टेस्ट नाम का मान लेता है।

Skip

मानक Robot Skip इस्तेमाल करें। Skip reason परिणाम में comment के रूप में जुड़ता है।

*** Test Cases ***
Login
    [Tags]    tracera.id:42    tracera.name:e2e/login
    Skip    env not ready — https://example.com/skip

स्टेप्स

टेस्ट में keywords परिणाम के टेस्ट सेक्शन के स्टेप्स बनते हैं। Test Setup और Test Teardown → परिणाम के सेटअप और टीयरडाउन; Suite Setup और Suite Teardown रिपोर्ट नहीं होते।

*** Settings ***
Test Setup       Open Shop
Test Teardown    Cleanup

*** Keywords ***
Open Shop
    Log    opening

Add To Cart
    Log    adding

Cleanup
    Log    done

*** Test Cases ***
Checkout
    [Tags]    tracera.id:10    tracera.name:e2e/checkout
    Add To Cart

डिफ़ॉल्ट स्टेप शीर्षक keyword नाम है (Add To Cart)। अलग शीर्षक के लिए:

*** Settings ***
Library    tracera_robot.keywords.TraceraKeywords

*** Test Cases ***
Checkout
    [Tags]    tracera.id:10
    Tracera Step    add sku-1    Add To Cart

Add To Cart चलेगा; परिणाम में स्टेप शीर्षक add sku-1 होगा।

Python सहायक फ़ंक्शन में core से tracera.step या @tracera.step("…") भी इस्तेमाल कर सकते हैं।

ये भी रिपोर्ट होते हैं: FOR, IF, WHILE, TRY, ELSE, EXCEPT और FINALLY (लूप की पुनरावृत्तियाँ नहीं)। TraceraKeywords की कॉल स्टेप के रूप में रिपोर्ट नहीं होतीं।

टिप्पणियाँ, त्रुटियाँ और अटैचमेंट

टिप्पणी, त्रुटियाँ और अटैचमेंट: ऑटोटेस्ट एडेप्टर।

*** Settings ***
Library    tracera_robot.keywords.TraceraKeywords

*** Keywords ***
Open Login
    Tracera Comment    landed on login
    Tracera Attach Text    suite-log.txt    finished login flow

*** Test Cases ***
Login
    [Tags]    tracera.id:42    tracera.name:e2e/login
    Tracera Comment    result-level note
    Tracera Error    result-level error text
    Open Login

डिस्क से फ़ाइल अटैच करें: Tracera Attach File ${path} image/png।

पैरामीटराइज़्ड टेस्ट

Robot [Template] के साथ टेस्ट पर [Tags] टेम्पलेट के नीचे हर आर्ग्युमेंट पंक्ति पर लागू होते हैं:

*** Test Cases ***
Login row
    [Tags]    tracera.id:42    tracera.name:e2e/login
    [Template]    Open Path
    /login
    /login/sso

*** Keywords ***
Open Path
    [Arguments]    ${path}
    Log    ${path}