Tracera
بدء التجربة

Robot Framework

pip install tracera-robot

يتطلب Python ≥ 3.11 وRobot Framework ≥ 7 (انظر محوّلات الاختبار الآلي). tracera-robot على PyPI.

سجّل الـ listener:

robot --listener tracera_robot.listener.TraceraListener suite.robot

مكتبة مرافقة اختيارية للتعليق والخطأ والمرفق وTracera Step وTracera Test Case:

*** Settings ***
Library    tracera_robot.keywords.TraceraKeywords

متغيرات البيئة ووضع التشغيل: محوّلات الاختبار الآلي.

ربط testCaseId و autotestName

فضّل الوسوم على الاختبار.

*** Test Cases ***
Login
    [Tags]    tracera.id:42    tracera.name:e2e/login
    Log    hello

عند الحاجة، رمّز المسافات والرموز الخاصة في tracera.name (e2e%2Flogin). إذا لم يُحدَّد tracera.name، فإن autotestName يأخذ قيمة اسم اختبار Robot.

Skip

استخدم Skip القياسي في Robot. يُضاف سبب التخطّي إلى النتيجة كـ comment.

*** Test Cases ***
Login
    [Tags]    tracera.id:42    tracera.name:e2e/login
    Skip    env not ready — https://example.com/skip

الخطوات

الكلمات في الاختبار تصبح خطوات ضمن قسم الاختبار للنتيجة. Test Setup وTest Teardown → الإعداد والتنظيف للنتيجة؛ Suite Setup وSuite Teardown لا تُبلَّغ.

*** Settings ***
Test Setup       Open Shop
Test Teardown    Cleanup

*** Keywords ***
Open Shop
    Log    opening

Add To Cart
    Log    adding

Cleanup
    Log    done

*** Test Cases ***
Checkout
    [Tags]    tracera.id:10    tracera.name:e2e/checkout
    Add To Cart

عنوان الخطوة الافتراضي هو اسم الكلمة (Add To Cart). لعنوان مختلف:

*** Settings ***
Library    tracera_robot.keywords.TraceraKeywords

*** Test Cases ***
Checkout
    [Tags]    tracera.id:10
    Tracera Step    add sku-1    Add To Cart

يُنفَّذ Add To Cart؛ عنوان الخطوة في النتيجة هو add sku-1.

يمكنك أيضًا لف دوال Python المساعدة بـ tracera.step أو @tracera.step("…") من core.

يُبلَّغ أيضًا: FOR وIF وWHILE وTRY وELSE وEXCEPT وFINALLY (دون تكرارات الحلقة). استدعاءات TraceraKeywords لا تُبلَّغ كخطوات.

التعليقات والأخطاء والمرفقات

التعليقات والأخطاء والمرفقات: محوّلات الاختبار الآلي.

*** Settings ***
Library    tracera_robot.keywords.TraceraKeywords

*** Keywords ***
Open Login
    Tracera Comment    landed on login
    Tracera Attach Text    suite-log.txt    finished login flow

*** Test Cases ***
Login
    [Tags]    tracera.id:42    tracera.name:e2e/login
    Tracera Comment    result-level note
    Tracera Error    result-level error text
    Open Login

أرفق ملفًا من القرص بـ Tracera Attach File ${path} image/png.

الاختبارات ذات المعاملات

مع Robot [Template]، تنطبق [Tags] على الاختبار على كل سطر وسيط تحت القالب:

*** Test Cases ***
Login row
    [Tags]    tracera.id:42    tracera.name:e2e/login
    [Template]    Open Path
    /login
    /login/sso

*** Keywords ***
Open Path
    [Arguments]    ${path}
    Log    ${path}

لمعرّف حالة مختلف لكل سطر وسيط: اختبار منفصل مع [Tags] الخاصة به (كما في الربط).